########################################################
##  u2.g     by L.Fortunato and W.A.de Graaf      (2011)
########################################################
##  This is a GAP4 script - needs SLA package by W.A.de Graaf
##  
##  It comes as auxiliary material to the paper  "Angular momentum non conserving 
##  symmetries in bosonic models"  L.Fortunato, W.A. de Graaf, J.Phys.A : Math. Theor. 44, 145206 (2011)
##
##  u(2) Lie algebra is implemented following the definitions in ch. 1 of the book
##  "Symmetry methods in molecules and nuclei" by A.Frank and P.van Isacker,
##  SyG Editores, Mexico (2005)
##
########################################################
T:=EmptySCTable(4,0,"antisymmetric");
SetEntrySCTable(T,1,2,[1, 2]);
SetEntrySCTable(T,1,3,[-1, 3]);
SetEntrySCTable(T,2,3,[1, 1,-1,4]);
SetEntrySCTable(T,2,4,[1, 2]);
SetEntrySCTable(T,3,4,[-1, 3]);


Print("\n");
F:=DefaultField(1);
Print("F=",F,"\n");
L:=AlgebraByStructureConstants(F,T);
Print("L=",L,"\n\n");
Print("Jacobi-> ",TestJacobi(T),"\n" );
Ba:=Basis(L);
Print("Ba=",Ba,"\n\n");

g:=KillingMatrix(Basis(L));
Print(g,"\n");
Print("det=",Determinant(g),"\n\n");

LM:=LeviMalcevDecomposition(L);
Print("Levi-Malcev Decomposition:",LM,"\n");
bs:=BasisVectors(Basis(LM[1]));
br:=BasisVectors(Basis(LM[2]));
Print("LM[2] -Basis of radical subalg of dim ",Dimension(LM[2]),": ",br, "\n");
Print("LM[1] -Basis of semisim subalg of dim ",Dimension(LM[1]),": ",bs, " of type ",SemiSimpleType(LM[1]),"\n" );

nil:=LieNilRadical(L);
no:=NilpotentOrbits(LM[1]);
Print(no, "\n");
Print("n.o. 1 -> WDD ", WeightedDynkinDiagram(no[1]) , "\n");